Din formel räknar väl bara antalet ifyllda och sen går den så många steg åt höger?

En variant är att istället returnera det högsta kolumnnumret, bland de celler som inte är tomma (<>"")

dvs det högsta värdet av: (D2:BC2<>"")*KOLUMN(D2:BC2)

När en cell är ifylld blir (D2:BC2<>"") = 1, annars 0. Så kolumnnumret multipliceras med 0 när cellen är tom och maxvärdet för kolumnnumret räknas bara när cellen är ifylld.

{=MAX((D2:BC2<>"")*KOLUMN(D2:BC2)))}

Måste vara matrisformel. För att slippa det är det enklast att lägga in den i en produktsumma:

=PRODUKTSUMMA(MAX((D2:BC2<>"")*KOLUMN(D2:BC2)))

Vilket ger kolumn 10 (j) som sista/högsta ifyllda kolumn.

Nu, när du vet det högsta kolumnnumret, kan du t.ex använda förskjutning (i förhållande till A-kolumnen) för att returnera rätt område

=PRODUKTSUMMA(MAX((D2:BC2<>"")*KOLUMN(D2:BC2))) - 5  ger rätt kolumn att starta i, sen utökar vi området med 5-steg åt höger

=FÖRSKJUTNING(A2;0;PRODUKTSUMMA(MAX((D2:BC2<>"")*KOLUMN(D2:BC2)))-5;1;5)

Och kollar medel på det

=MEDEL(FÖRSKJUTNING(A2;0;PRODUKTSUMMA(MAX((D2:BC2<>"")*KOLUMN(D2:BC2)))-5;1;5))

=AVERAGE(OFFSET(A2;0;SUMPRODUCT(MAX((D2:BC2<>"")*COLUMN(D2:BC2)))-5;1;5))

PS -varning

Förskjutning är lite trickigt även om det råkar bli rätt den här gången. När du går 10 steg till höger om A1 Hamnar du faktiskt i 11:e kolumnen, inte 10:e (som index skulle ha gjort). Normalt sett får man alltid klämma in -1 Men nu råkar det bli så lyckligt att när du tar -5 så hamnar du i 6:e kolumnen vilket är precis där du ville starta. Det normala är att man får man tänka till ett varv extra. Normalt sett skulle jag ha skrivit så här, dvs hitta J2 och utöka området -5 steg

=MEDEL(FÖRSKJUTNING(A2;0;PRODUKTSUMMA(MAX((D2:BC2<>"")*KOLUMN(D2:BC2)))-1;1;-5))

 Precis samma resultat men lite olika pedagogik. 

 Vet inte om jag förstår hur du menar.

Menar du att du bara vill lägga till bokstäver som ”uteslutningsvillkor”? Då kan du byta ut

(D2:BC2<>"")*   mot ÄRTAL:  (ISNUMBER(D2:BC2)*

Men då räcker inte produktsumman för att excel skall förstå att det är en matrisformel. Du måste ändå mata in med Ctrl+shift+enter.

Alternativ:

Om vi antar att du vill returnera värdet för de 5 högsta Veckonumren oavsett om det kommer tomma celler/ bokstäver emellan
(t.ex både före/efter semester) så tror jag att du får plocka ut dom en och en med hjälp av STÖRSTA (LARGE) som tillåter att du
hämtar ut det X-största värdet (radnumret) i en lista

Om du matar in de här formlerna som matrisformler (Ctrl+shift+enter) så får du kolumnnumret för den största,
näst största och tredje största kolumnnumret som innehåller en siffra

{=STÖRSTA(ÄRTAL(D2:BC2)*KOLUMN(D2:BC2);1)}

{=STÖRSTA(ÄRTAL(D2:BC2)*KOLUMN(D2:BC2);2)}

{=STÖRSTA(ÄRTAL(D2:BC2)*KOLUMN(D2:BC2);3)}

(LARGE, ISNUMBER, COLUMN)

Kolla hur det ändras om du skriver i 0:or, tal eller bokstäver i rad2

När du vet kolumnnumren kan du återigen fiska ut värdet med hjälp av FÖRSKJUT eller INDEX. Så här blir formeln för det största med hjälp av INDEX
(Hmm, jag vet att jag valde bort index av någon anledning i går, men nu kommer jag inte ihåg varför. Men, men: det blir kompaktare).

{=INDEX(A2:BD2;1;STÖRSTA(ÄRTAL(D2:BC2)*KOLUMN(D2:BC2);1))}

Sen skulle man kunna tro att man kan fiska ut de 5 största genom att lägga en matris i n:te största och summera

{=summa(INDEX(A2:BD2;1;STÖRSTA(ÄRTAL(D2:BC2)*KOLUMN(D2:BC2);{1;2;3;4;5})))}

Men det verkar inte gå, så du får räkna ihop var för sig (som jag tror att den blir med dina Svengelska inställningar). en kort och kompakt formel (du måste utöka formelfönstret om du villl se mer än en rad)...:

{=AVERAGE(INDEX(A2:BD2;1;LARGE(ISNUMBER(D2:BC2)*COLUMN(D2:BC2);1));
INDEX(A2:BD2;1;LARGE(ISNUMBER(D2:BC2)*COLUMN(D2:BC2);2));
INDEX(A2:BD2;1;LARGE(ISNUMBER(D2:BC2)*COLUMN(D2:BC2);3));
INDEX(A2:BD2;1;LARGE(ISNUMBER(D2:BC2)*COLUMN(D2:BC2);4));
INDEX(A2:BD2;1;LARGE(ISNUMBER(D2:BC2)*COLUMN(D2:BC2);5)))}

Möjliga Problem:

Det får inte stå några siffror i kolumn A:C. Det ger problem om mindre än 5 ”giltiga” värden

Det börjar på A2 för att det är bekvämast. STÖRSTA returnerar kolumnnummer. Om man börjar i A2 så slipper man räkna om det till position i D2:DC2  (dvs ta -3).

Hursomhelst. Det löser inte problemet att ändra idex-intervallet till D2:DC2  . Så fort det finns mindre än 5 tal så hamnar man på negativa index och då blir det konstigt ändå.

En variant är att du kör en OMsats och kollar om det finns X siffror ifyllda innan du inkluderar den x:te högsta kolumnen. Om det Exempelvis finns färre än 5 siffror i intervallet så returnerar Excel 0 istället för attt försöka hitta det 5:e minsta talet med den här formeln:

OM(ANTAL(D2:BC2)<5;0;INDEX(D2:BC2;1;STÖRSTA(ÄRTAL(D2:BC2)*KOLUMN(D2:BC2);5)-3))

OBS att ANTAL/COUNT bara räknar siffror (till skillnad mot ANTALV/CONTA). Så vi behöver inte skriva något villkor för den delen. 

För att få ut medel så åtegår vi till din ursprungsformel och summera varefter du dividerar med antal ifyllda tal 

{=SUMMA(
OM(ANTAL(D2:BC2)<1;0;INDEX(D2:BC2;1;STÖRSTA(ÄRTAL(D2:BC2)*KOLUMN(D2:BC2);1)-3));
OM(ANTAL(D2:BC2)<2;0;INDEX(D2:BC2;1;STÖRSTA(ÄRTAL(D2:BC2)*KOLUMN(D2:BC2);2)-3));
OM(ANTAL(D2:BC2)<3;0;INDEX(D2:BC2;1;STÖRSTA(ÄRTAL(D2:BC2)*KOLUMN(D2:BC2);3)-3));
OM(ANTAL(D2:BC2)<4;0;INDEX(D2:BC2;1;STÖRSTA(ÄRTAL(D2:BC2)*KOLUMN(D2:BC2);4)-3));
OM(ANTAL(D2:BC2)<5;0;INDEX(D2:BC2;1;STÖRSTA(ÄRTAL(D2:BC2)*KOLUMN(D2:BC2);5)-3))
)/ANTAL(D2:BC2)}

Svengelsk utan radbrytningar:

=SUM(IF(COUNT(D2:BC2)<1;0;INDEX(D2:BC2;1;LARGE(ISNUMBER(D2:BC2)*COLUMN(D2:BC2);1)-3));IF(COUNT(D2:BC2)<2;0;INDEX(D2:BC2;1;LARGE(ISNUMBER(D2:BC2)*COLUMN(D2:BC2);2)-3));IF(COUNT(D2:BC2)<3;0;INDEX(D2:BC2;1;LARGE(ISNUMBER(D2:BC2)*COLUMN(D2:BC2);3)-3));IF(COUNT(D2:BC2)<4;0;INDEX(D2:BC2;1;LARGE(ISNUMBER(D2:BC2)*COLUMN(D2:BC2);4)-3));IF(COUNT(D2:BC2)<5;0;INDEX(D2:BC2;1;LARGE(ISNUMBER(D2:BC2)*COLUMN(D2:BC2);5)-3)))/COUNT(D2:BC2)